윈도우 서버 2012 제품 키 확인 - windou seobeo 2012 jepum ki hwag-in

티스토리 뷰

윈도우의 제품 번호를 알아보기.

☞시작--실행 에서 regedit 입력하고 엔터를 합니다.

HKEY_LOCAL_MACHINESoftwareMicrosoftWindowsCurrentVersio 항목 선택,
오른쪽 창의 ProductKey에 제품번호가 적혀있다.

☞ 도스로 부팅 해야만 하는 경우

c:system.1st 파일의 속성을 모두 해제한 다음 도스용 에디터로
productkey를 찾으면 제 번호가 보인다

Windows 11 Windows 10 Windows 8.1 Windows 7 Microsoft 계정 대시보드 더 보기...간단히

추가 도움이 필요하신가요?

윈도우 서버 시리얼 넘버 모음

Operating systemProduct key

Windows Server 2008 Standard	TM24T-X9RMF-VWXK6-X8JC9-BFGM2
Windows Server 2008 Enterprise	YQGMW-MPWTJ-34KDK-48M3W-X4Q6V
Windows Server 2008 Datacenter	7M67G-PC374-GR742-YH8V4-TCBY3
Windows Server 2008 R2 Standard	YC6KT-GKW9T-YTKYR-T4X34-R7VHC
Windows Server 2008 R2 Enterprise	489J6-VHDMP-X63PK-3K798-CPX3Y
Windows Server 2008 R2 Datacenter	74YFP-3QFB3-KQT8W-PMXWJ-7M648
Windows Server 2012 Standard	XC9B7-NBPP2-83J2H-RHMBY-92BT4
Windows Server 2012 Datacenter	48HP8-DN98B-MYWDG-T2DCC-8W83P
Windows Server 2012 R2 Standard	D2N9P-3P6X9-2R39C-7RTCD-MDVJX
Windows Server 2012 R2 Datacenter	W3GGN-FT8W3-Y4M27-J84CP-Q3VJ9
Windows 8.1 Professional	GCRJD-8NW9H-F2CDX-CCM8D-9D6T9
Windows Server 2016 Datacenter	CB7KF-BWN84-R7R2Y-793K2-8XDDG
Windows Server 2016 Standard	WC2BQ-8NRM3-FDDYY-2BFGV-KHKQY
Windows Server 2016 Essentials	JCKRF-N37P4-C2D82-9YXRT-4M63B
Windows Server 2019 Standard	N69G4-B89J2-4G8F4-WWYCC-J464C
Windows Server 2019 Datacenter	WMDGN-G9PQG-XVVXX-R3X43-63DFG

2008, 2012, 2016, 2019, DataCenter, R2, Standard, 서버, 윈도우, 키젠

댓글

안녕하세요. RootKR입니다.

윈도우 제품키(시디키)를 분실해서 프로그램을 이용해서 제품키를 찾아야하는 경우가 있는데

블로그상에 배포중인 프로그램은 바이러스 포함되어있을수도있고 배포자에게 전송될까봐 불안할 수 있습니다.

아래 윈도우 내장 스크립터를 이용하면 프로그램 없이 윈도우 제품키(시디키)를 확인할 수 있습니다.

FPP(처음사용자용), DSP, OEM키만 확인가능하며 MAK키는 확인 불가능합니다.

1. 글 마지막에 위치한 윈도우 내장 스크립터를 복사후 메모장에 붙여넣어주세요.

2. 파일, 다른 이름으로 저장(A) 순서대로 클릭후 윈도우 내장 스크립터를 저장해주세요.

3. 파일 형식은 모든 파일(*.*) 선택후 파일이름은 windows-cd-key-check.vbs 입력후 저장(S)버튼을 클릭해주세요.

저장한 윈도우 내장 스크립터를 실행하면 윈도우 제품키(시디키)가 나옵니다.

예(Y) 버튼을 클릭하면 친절하게 윈도우 제품키(시디키)를 저장해줍니다.

윈도우 7, 비스타, XP

Set WshShell = WScript.CreateObject("WScript.Shell")

KeyPath = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\DigitalProductId"
MsgBox ExtractKey(WshShell.RegRead(KeyPath))

Function ExtractKey(KeyInput)
    Const KeyOffset = 52
    i = 28
    CharWhitelist = "BCDFGHJKMPQRTVWXY2346789"
    Do
        Cur = 0
        x = 14
        Do
            Cur = Cur * 256
            Cur = KeyInput(x + KeyOffset) + Cur
            KeyInput(x + KeyOffset) = (Cur \ 24) And 255
            Cur = Cur Mod 24
            x = x -1
        Loop While x >= 0
        i = i -1
        KeyOutput = Mid(CharWhitelist, Cur + 1, 1) & KeyOutput
        If (((29 - i) Mod 6) = 0) And (i <> -1) Then
            i = i -1
            KeyOutput = "-" & KeyOutput
        End If
    Loop While i >= 0
    ExtractKey = KeyOutput
End Function

윈도우 10, 8.1, 8

Option Explicit 

Dim objshell,path,DigitalID, Result 
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID) 
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
'Show messbox if save to a file 
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
   Save ProductData 
End If



'Convert binary to chars
Function ConvertToKey(Key)
    Const KeyOffset = 52
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
    'Check if OS is Windows 8
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Maps = "BCDFGHJKMPQRTVWXY2346789"
    Do
       Current= 0
        j = 14
        Do
           Current = Current* 256
           Current = Key(j + KeyOffset) + Current
           Key(j + KeyOffset) = (Current \ 24)
           Current=Current Mod 24
            j = j -1
        Loop While j >= 0
        i = i -1
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
        Last = Current
    Loop While i >= 0 
    keypart1 = Mid(KeyOutput, 2, Last)
    insert = "N"
    KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
    If Last = 0 Then KeyOutput = insert & KeyOutput
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
   
    
End Function
'Save data to a file
Function Save(Data)
    Dim fso, fName, txt,objshell,UserName
    Set objshell = CreateObject("wscript.shell")
    'Get current user name 
    UserName = objshell.ExpandEnvironmentStrings("%UserName%") 
    'Create a text file on desktop 
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set txt = fso.CreateTextFile(fName)
    txt.Writeline Data
    txt.Close
End Function

소스 : VBS Script to get the Windows(R) 7 Product Key from a PC's registry. - https://gist.github.com/eyecatchup/d577a2628666a0ad1375, How to view your product key in Windows 10, Windows 8 and Windows 7 - https://winaero.com/blog/how-to-view-your-product-key-in-windows-10-windows-8-and-windows-7/